13 – Cantautore
Apparso da pagina 85 fino a pagina 90 de “Il libro dei giochi del Commodore 64”
Il listato pubblicato
Il programma
Il nostro listato digitato
Qui di seguito trovate il codice da copiare sul programma CBM prg Studio Il codice originale é stato modificato affinchè possa essere letto da CBM prg Studio. I caratteri speciali PETSCII (Screen Codes) presenti nel listato originale, sono stati singolarmente sostituiti da quelli standard utilizzati da CBM prg Studio. Attenzione – Grazie alla segnalazione di più utenti, i caratteri “<” e “>” potrebbero venir sostituiti dai rispettivi encoding html “<” e “>” . Qualora li trovaste, sostituite manualmente questi valori direttamente su CBM prg Studio, altrimenti il programma non funzionerà. Scusate per l’inconveniente tecnico.
10 rem **cantautore**
20 forj=0to24:poke54272+j,0:next
30 v=54272:pokev+5,9:pokev+6,130:z=0
40 deffnr(x)=int(rnd(1)*x)+1
50 print"{clear}{white}{down*3}":poke53280,5:poke53281,10
60 x$(1)=" called ":x$(2)=" of "
70 y$(1)=" always ":y$(2)=" never ":y$(3)=" seldom "
80 z$(1)=" day ":z$(2)=" night "
90 pokev+24,15:forj=1to41
100 readfh,fl,d
110 pokev,fl:pokev+1,fh:pokev+4,33
120 fork=1to150*d
130 next
140 pokev+4,32
150 next:pokev+24,0
160 ifz=0thenz=1:goto200
170 print"{blue} ancora ? {up}"
180 geta$:ifa$=""then180
190 ifa$="s"thenrestore:goto90
200 rx=fnr(2):ry=fnr(3):rz=fnr(2)
210 print"{clear}{white}":forj=1to7
220 readq,s
230 ifj=4thenrr=fnr(2):w=(rx-1)*s/q+(rq-1)*q+rr:goto290
240 rq=fnr(q)
250 p=1
260 ifj=3thenp=rx
270 ifj=5thenp=rz
280 w=(p-1)*q+rq
290 fork=1tow
300 readw$(j)
310 next
320 ifk=s+1then360
330 fork=w+1tos
340 readw$
350 next
360 next
370 v$="there was a "+w$(1)+" "+w$(2)+x$(rx)+w$(3)
380 print:printv$
390 v$="who"+y$(ry)+w$(4)
400 print:printv$
410 v$="then "+w$(5)
420 print:printv$
430 v$="one "+w$(6)+z$(rz)
440 print:printv$
450 v$="that "+w$(7)+" "+w$(1)+" "+w$(2)+x$(rx)+w$(3)
460 print:printv$
470 restore
480 print"{down*3}{blue} vuoi cantarlo ?{up}"
490 geta$:ifa$=""then490
500 ifa$="s"then90
510 forj=1to123
520 readx
530 next
540 goto200
1000 data16,195,1,22,96,2,22,96,1,22,96,1,22,96,2,21,31,1
1010 data18,209,1,21,31,2,25,30,3,0,0,1,16,195,1,25,30,2
1020 data25,30,1,25,30,1,25,30,2,22,96,1,21,31,1,22,96,2
1030 data28,49,3,0,0,1,28,49,1,33,35,2,33,135,1,33,135,1
1040 data33,135,2,0,0,1,28,49,1,29,223,2,29,223,1,29,223,1
1050 data29,223,2,0,0,1,25,30,1,28,49,2,33,135,1,28,49,1
1060 data29,223,2,28,49,1,25,30,1,28,49,2,22,96,2
2000 data4,4,fat,great,sly,bright
3000 data4,4,writer,loafer,artist,beauty
4000 data3,6,nelly,parkin,neville
4010 dataluton,ely,norwich
5000 data2,12,threw bricks at the telly,ate ice cream and jelly
5010 dataset all the dogs barking,was fooling and larking
5020 datasaid 'i'm a real devil',was quite on the level
5030 datawent huntin' and shootin',played chess with his boots on
5040 datasaid 'is it true? - really?',had eyes that were steely
5050 dataate mustard with porridge,lacked vigour and courage
6000 data3,6,spent all his pay,fell in the bay,joined the aa
6010 datadied of sheer fright,put out the light,looked such a sight
7000 data5,5,terrible,cold frosty,ill fated,fabulous,memorable
8000 data6,6,stupid,clever,lazy,crafty,evil,pretty
Il file .PRG del listato
Provalo direttamente sull’emulatore! Clicca sul pulsante per avviare!
Downloading…