Il libro dei giochi del Commodore 64 – 20 – Poker Joe

 328 total views,  2 views today

20 – Poker Joe

Apparso da pagina 133 fino a pagina 139 de “Il libro dei giochi del Commodore 64”

Il listato pubblicato

Il programma

Il nostro listato digitato

Qui di seguito trovate il codice da copiare sul programma CBM prg Studio Il codice originale é stato modificato affinchè possa essere letto da CBM prg Studio. I caratteri speciali PETSCII (Screen Codes) presenti nel listato originale, sono stati singolarmente sostituiti da quelli standard utilizzati da CBM prg Studio. Attenzione – Grazie alla segnalazione di più utenti, i caratteri “<” e “>” potrebbero venir sostituiti dai rispettivi encoding html “&lt;” e “&gt;” . Qualora li trovaste, sostituite manualmente questi valori direttamente su CBM prg Studio, altrimenti il programma non funzionerà. Scusate per l’inconveniente tecnico.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
10 rem **poker joe**
20 poke251,100:poke252,100
30 print"{clear}";:poke53280,13:poke53281,13:ps=peek(251):ys=peek(252)
40 dimp%(12,3),h%(12,7),d%(12,1)
50 forj=1to10
60 d=int(rnd(1)*13):s=int(rnd(1)*4)
70 ifp%(d,s)=1then60
80 p%(d,s)=1
90 ifj>5thens=s+4
100 h%(d,s)=1
110 next
120 print"{brown}{down}{right*2}le tue carte sono:{down*2}"
130 printtab(5)"{black}{orange}  ";:s=4:gosub1000
140 print"{down}":printtab(5)"{red}S  ";:s=5:gosub1000
150 print"{down}":printtab(5)"Z  ";:s=6:gosub1000
160 print"{down}":printtab(5)"{black}X  ";:s=7:gosub1000
170 forj=0to12:forh=0to1:fork=0+h*4to3+h*4
180 ifh%(j,k)=1thend%(j,h)=d%(j,h)+1
190 next:next:next
200 forh=0to1:fork=h*4to3+h*4:forj=0to12
210 ifh%(j,k)=1thens%(k)=s%(k)+1
220 next:next:next
230 s=0:forh=0to1
240 fork=h*4to3+h*4
250 ifs%(k)=5thens=k
260 next:ifs=0then360
270 r=0:forj=12to4step-1
280 f=1:forl=jtoj-4step-1
290 ifh%(l,s)<>1thenf=0
300 next
310 iff=1thenr=j
320 next
330 ifr=122thens(h)=1:goto360
340 ifr>0andr<12thens(h)=2:goto360
350 s(h)=5
360 next
370 forh=0to1
380 ifs(h)>0then500
390 forj=0to12
400 c%(d%(j,h),h)=1
410 next
420 f=0:forj=0to12
430 ifd%(j,h)=2thenf=f+1
440 next
450 iff=2thenc%(2,h)=2
460 ifc%(4,h)=1thens(h)=3:goto500
470 ifc%(3,h)=1andc%(2,h)=1thens(h)=4:goto500
480 ifc%(3,h)=1thens(h)=7:goto500
490 ifc%(2,h)>0thens(h)=10-c%(2,h)
500 next
510 forh=0to1
520 ifs(h)>0then570
530 forj=0to8
540 f=1:forl=jtoj+4:ifd%(l,h)=0thenf=0
550 next:iff=1thens(h)=6
560 next
570 next
580 forh=0to1
590 ifs(h)>0then630
600 f=0:forj=12to0step-1
610 ifd%(j,h)=1andf=0thens(h)=10+j:f=1
620 next
630 next
640 print:print"{dark gray}{down*2}{right*2}poker joe ";
650 ifrnd(1)>.9thenm=int(rnd(1)*11):goto680
660 m=s(0)+int(rnd(1)*3)-2
670 ifm<1thenm=1
680 ifm>10thenm=10
690 forj=0to12:readd$:next
700 forj=1tom:readm$:next
710 printm$
720 print"{brown}{down*2}{right*2}cosa vuoi fare ?"
730 geta$:ifa$=""then730
740 ifa$="p"thenps=ps+1:ys=ys-1:goto910
750 ifa$="v"then770
760 goto730
770 ifm=10then790
780 forj=m+1to10:readm$:next
790 m=s(0):ifm>10thenm=10
800 forj=1tom:readh$:next:restore
810 print"{home}";tab(20)"{down}poker joe ha :{down}":print:printtab(22)"{black}A  ";:s=0:gosub1000
820 print:printtab(22)"{red}{down}S  ";:s=1:gosub1000
830 print:printtab(22)"{red}{down}Z  ";:s=2:gosub1000
840 print:printtab(22)"{black}{down}X  ";:s=3:gosub1000
850 print"{dark gray}{down*7}":print"{right*2}poker joe ha:{right}";
860 printh$
870 ifs(0)>9ands(1)>9thens(0)=-s(0):s(1)=-s(1)
880 ifs(0)<s(1)thenprint"{right*2}e vince!!":ps=ps+2:ys=ys-2:goto910
890 ifs(0)>s(1)thenprint"{right*2}e perde!!":ps=ps-3:ys=ys+3:goto910
900 print"{right*2}cosi' e' patta!!"
910 print:printtab(5)"{brown}tu:  ";ys;tab(25)"{dark gray}p-j:  "ps
920 geta$:ifa$<>" "then920
930 poke251,ps:poke252,ys:clr:goto30
1000 forj=12to0step-1
1010 readd$
1020 ifh%(j,s)<>0thenprintd$;" ";
1030 next
1040 restore
1050 return
3000 dataa,k,q,j,10,9,8,7,6,5,4,3,2
4000 datasta ghignando,sta boccheggiando,sta sorridendo,e' imperscrutabile
4010 datae' perplesso,ti sta guardando,ha afferrato il tavolo
4020 datasembra misterioso,sta impallidendo,sta boccheggiando
5000 datauna scala reale massima,una scala reale,un poker,un full,un colore
5010 datauna scala,un tris,una doppia coppia,coppia,una carta piu' alta

Il file .PRG del listato

Clicca qui per scaricarlo

Provalo direttamente sull’emulatore! Clicca sul pulsante per avviare!

Downloading…

L’emulatore C64 online è ad utilizzo libero solo per usi non-commerciali. Leggere le license agreement per ulteriori dettagli.

Ringraziamo l’autore per averlo creato e messo a disposizione!

Copyright © 2021 Thomas Hochgoetz. Tutti i diritti riservati.

https://c64emulator.111mb.de/

 

Ritorna alla pagina precedente